?Laplacian

Cartesian

Laplacian[f[x,y,z],{x,y,z},"Cartesian"]

tmp1=Laplacian[xx[x] yy[y] zz[z],{x,y,z},"Cartesian"]/(xx[x] yy[y] zz[z]) //Expand

D[(E^(α x)),{x,2}]

tmp1 /.{((xx''[x])/(xx[x]))->(α^2),((yy''[y])/(yy[y]))->(β^2),((zz''[z])/(zz[z]))->(γ^2)}

DSolve[ xx''[x]== (α^2) xx[x],xx[x],x]

Plot[{Sin[x],Cos[x]},{x,-5,5},PlotStyle->{Red,Blue}]

Plot[{Sinh[x],Cosh[x]},{x,-5,5},PlotStyle->{Red,Blue}]

Cylindrical

Clear["Global`*"]

tmp1= ((Laplacian[fr[r]fθ[θ] fz[z],{r,θ,z},"Cylindrical"])/(fr[r]fθ[θ] fz[z]))//Expand

tmp2= tmp1 /.{((fz''[z])/(fz[z]))->+(m^2)}

DSolve[fz''[z]== (m^2)fz[z],fz[z],z]

tmp3= tmp2 (r^2)  /.{(((fθ)''[θ])/(fθ[θ]))->-(α^2)}//Expand

DSolve[ (fθ)''[θ]==-(α^2)fθ[θ],fθ[θ],θ]

tmp4=tmp3    //Expand

DSolve[tmp4==0,fr[r],r]

?BesselJ

Plot[Table[ BesselJ[n,r],{n,0,5}] //Evaluate,{r,0,10}]

Plot[Table[ BesselY[n,r],{n,0,5}] //Evaluate,{r,0,5}]

Bessel orthogonality

zeros=Table[ BesselJZero[1,n],{n,1,10}];
zeros //N

tab1 = Table[ Integrate[ r BesselJ[1,zeros[[1]] r]BesselJ[1,zeros[[n]] r],{r,0,1}],{n,1,10}]

tab3 = Table[ Integrate[ r BesselJ[1,zeros[[3]] r]BesselJ[1,zeros[[n]] r],{r,0,1}],{n,1,10}]

tab1[[1]] //FullSimplify

Integrate[ LegendreP[1,x] LegendreP[2,x],{x,-1,1}]

Spherical

Clear["Global`*"]

tmp1= ((Laplacian[fr[r]fθ[θ] fϕ[ϕ],{r,θ,ϕ},"Spherical"])/(fr[r]fθ[θ] fϕ[ϕ]))//Expand

tmp2= tmp1  //Expand

tmp3= tmp2 /.{(((fϕ)''[ϕ])/(fϕ[ϕ]))->-(m^2)}

DSolve[fϕ''[ϕ]== - (m^2)fϕ[ϕ],fϕ[ϕ],ϕ] //ExpToTrig

tmp4=tmp3 //Expand

tmp5r= Select[tmp4, FreeQ[#,θ]&]

tmp5θ= Select[tmp4, FreeQ[#,r]&]

tmp5θ+tmp5r ==tmp4

(tmp5θ + el(el+1)) +( tmp5r -+ el(el+1))== tmp4

eqr= fr[r](tmp5r -el(el+1))//Expand //Simplify

DSolve[ eqr ==0 ,fr,r]

(* We guess the form of the solution *)
rsol=DSolve[fr[r]==(r^a),fr,r][[1]]

tmp = eqr /.rsol //Simplify

asol=Solve[tmp==0,a]

(* Show the general form is: c1 (r^el)+ c2 (r^(-(el+1)))  *)
(r^a) /.asol

(* This approach is not useful  *)
DSolve[  eqr==0,fr[r],r] //FullSimplify //PowerExpand

eqθ=( tmp5θ+el(el+1)) fθ[θ] //Expand

DSolve[eqθ==0,fθ[θ],θ]

Plot[Table[ LegendreP[el,0,z],{el,0,5}] //Evaluate,{z,-1,1}]

Plot[Table[ LegendreQ[el,0,z],{el,0,5}] //Evaluate,{z,-1,1}]

Table[ {LegendreP[el,0,1],LegendreQ[el,0,1]},{el,0,5}]

?SphericalHarmonicY

ylm[el_,m_,θ_,ϕ_]=(Sqrt[(((2el+1)(el-m)!)/(4π(el+m)!))])(E^(I m ϕ))LegendreP[el,m,Cos[θ]]

ylm[1,0,θ,ϕ]

SphericalHarmonicY[1,0,θ,ϕ]

Table[ SphericalHarmonicY[1,0,θ,ϕ]==ylm[1,0,θ,ϕ],{el,0,3,1},{m,-el,el}]

(* Show the general form is: c1 (r^el)+ c2 (r^(-(el+1)))  *)

plot[el_, m_ ] :=SphericalPlot3D[
SphericalHarmonicY[el , m, θ, φ] //Abs//Evaluate,
{θ, 0, π}, {φ, 0, 2 π},
Axes->False,
Boxed->False
]
plot[2,1]

pt1=Table[plot[el, m], {el , 0, 2}, {m, -el, el}];
Show[GraphicsGrid[pt1]]

Legendre orthogonality

Integrate[ LegendreP[1,x] LegendreP[2,x],{x,-1,1}]

tab=Table[ Integrate[ LegendreP[m,x] LegendreP[n,x],{x,-1,1}],{m,1,10},{n,1,10}];

tab //MatrixForm

Heat Equation

Clear["Global`*"]

term[x_,y_,n_]=b[n] Exp[((-n π y)/10)] Sin[((n π x)/10)]

b[n_]=(2/10)Integrate[100 Sin[((n π x)/10)],{x,0,10}]

temp[x_,y_,n_]:=Sum[term[x,y,m],{m,1,n}]

temp[x,y,4]

Plot3D[ temp[x,y,10],{x,0,10},{y,0,10}]

Variable V[x,0]

Clear["Global`*"]

term[n_,x_,y_]:=  Sin[n π x] Exp[- n π y]

v[x_,0]=1

Plot3D[ term[1,x,y],{x,0,1},{y,0,1},PlotRange->All]

c[n_]=Integrate[  v[x,0] Sin[n π x]  ,{x,0,1}]

Limit[c[n],n->0]

c[0]=0

sum[m_,x_,y_]:=Sum[ c[n] term[n,x,y],{n,0,m}]

Plot3D[ sum[30,x,y],{x,0,1},{y,0,1},PlotRange->All]

BesselJ

Clear["Global`*"]

Plot[Table[ BesselJ[n,r  ],{n,0,5}] //Evaluate,{r,0,10}]

Table[BesselJZero[n,1],{n,1,5}] //N

Plot[Table[ BesselJ[n,BesselJZero[n,1] r  ],{n,0,5}] //Evaluate,{r,0,1}]

Plot[Table[ BesselJ[n,BesselJZero[n,2] r  ],{n,0,5}] //Evaluate,{r,0,1}]