6. Quantum Mechanics

Legal Notice, Disclaimer, and Book Ordering Information:

Null

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`PlotField3D`"]

<< "D:\Mma\Inits\ch6init.m"

Clear["Global`*"];

6.2 Problems

6.2.1  One Dimensional Schrödinger Equation

Problem 3:  Particle hitting a finite potential step.

Consider a particle of energy E approaching a potential barrier V[x] = 0 if x<0 and V[x] = V0 if x>=0.  The wave function to the left of the barrier (x<0) has an incident and a reflected wave.  The wave function to the right of the barrier (x>0) has only a transmitted wave.

Part (a)  Write the general form of the wave function in the regions x<0 and x>=0.  Use the boundary conditions at the barrier to evaluate the amplitudes to the reflected and transmitted waves.

waveExp[x,k,c1,c2]

kRule = {k -> Sqrt[2 m (En - V)]/ℏ}

kRule2 = {k1->k/.kRule/.V->0
		 ,k2->k/.kRule}

ψL[x_]:= waveExp[x,k1,1,R]

ψL[x]

ψR[x_]:= waveExp[x,k2,T,0]

ψR[x]

boundary={ψL[x] == ψR[x],ψL'[x] == ψR'[x]}//.{x->0}

RTrule = Solve[boundary,{R,T}]//Flatten

RTrule2 = RTrule//.kRule2//PowerExpand//Simplify

Part (b)  The coefficients of transmission T and reflection R are defined as thethe rations of transmitted and reflected current density compared to the incident current density, respectively.  Assume that En>V0 and find T and R.  Plot R and T as a function of En.

SetCoordinates[Cartesian[x,y,z]]

incFlux = flux[ψL[x][[1]] ]

Rflux = -flux[ψL[x][[2]] ]

Tflux = flux[ψR[x]]

{RR,TT}={Rflux[[1]]/incFlux[[1]],
		 Tflux[[1]]/incFlux[[1]]}/.RTrule

Clear[V]

values={m->1,ℏ->1,V->1}

Plot[{RR,TT}/.RTrule/.kRule2/.values//Evaluate
	,{En,1,2}
	,AxesLabel->{FontForm["En"  ,{"Courier-Bold",10}]
				,FontForm["Coef",{"Courier-Bold",10}]}
	,PlotStyle->{Dashing[{0.1,0.0}],Dashing[{0.01,0.02}]}
	,Epilog->Graphics[{
		 Text[FontForm["TT"  ,{"Courier-Bold",10}],{1.8,0.89}]
		,Text[FontForm["RR"  ,{"Courier-Bold",10}],{1.8,0.15}]}
	][[1]]];

Part (c)    Plot the real and imaginary parts of thr wave function for energies En above and below the barrier V.

values={m->1,ℏ->1,V->1}

ψ[x0_ /; x0<=0,Energy_]:=
	ψL[x]/.RTrule/.kRule2/.values/.{x->x0,En->Energy}

ψ[x0_ /; x0>0,Energy_]:=
	ψR[x]/.RTrule/.kRule2/.values/.{x->x0,En->Energy}

wavePlot2D[Energy_]:=
	Plot[{Re[ψ[x, Energy]],Im[ψ[x, Energy]]}//Evaluate
		,{x,-10,+10}
		,AxesLabel->{FontForm["x",{"Courier-Bold",10}]
					,FontForm["ψ",{"Symbol",10}]}
		,AxesOrigin->{0,0}
		,PlotStyle->{Dashing[{0.1,0.0}],Dashing[{0.03,0.02}]}
		,DisplayFunction->Identity];

Show@GraphicsArray[{wavePlot2D[1.2],wavePlot2D[0.9]}
		,DisplayFunction->$DisplayFunction];

Part (d)  Use Plot3D to grah the wave function as a function of the two parameters {x,En}.

wavePlot3D =
	Plot3D[Evaluate[#[ψ[x π, Energy]]]
		,{x,-10,+10},{Energy,0.5,1.5}
		,PlotPoints->35
		,AxesLabel->{"x","Energy","ψ"}
		,Ticks->{{-10,-5,{0,"Barrier"},5,10}
				,{5,{0.7,"E<V"},{1,"E=V"},{1.2,"E>V"},1.4}
				,{-2,-1,0,1,2}}
		]& /@ {Re,Im};

Part (e)  Animate the real part of the incident reflected, and transmitted waves.  Do the animation for energies above and below the barrier.

timePlot[time_,wave_,Energy_,thick_,xrange_] :=
	Plot[Evaluate[Re[Exp[-I Energy time]*wave
		/.RTrule/.kRule2/.values/.En->Energy ] ]
		,xrange
		,PlotStyle->{Dashing[{0.05,thick}]}
		,AxesOrigin->{0,0}
		,DisplayFunction->Identity];

tnumber=12;
timestep=2 π/tnumber;
Energy=1.1;
Do[Show[{timePlot[time,ψL[x][[1]],Energy,0,{x,-10,0}]
		,timePlot[time,ψL[x][[2]],Energy,.05,{x,-10,0}]
		,timePlot[time,ψR[x][[1]],Energy,.02,{x, 0,10}]}
	,DisplayFunction->$DisplayFunction]
	,{time,0,2 π - timestep,timestep}]

tnumber=12;
timestep=2 π/tnumber;
Energy=0.9;
Do[Show[{timePlot[time,ψL[x][[1]],Energy,0,{x,-10,0}]
		,timePlot[time,ψL[x][[2]],Energy,.05,{x,-10,0}]
		,timePlot[time,ψR[x][[1]],Energy,.02,{x, 0,10}]}
	,DisplayFunction->$DisplayFunction]
	,{time,0,2 π - timestep,timestep}]