6. Quantum Mechanics

Legal Notice, Disclaimer, and Book Ordering Information:

Null

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`ParametricPlot3D`"]

<< "D:\Mma\Inits\ch6init.m"

Clear["Global`*"];

6.2 Problems

6.2.1  One Dimensional Schrödinger Equation

Problem 5:  Thw one-dimensional harmonic oscillator.

Consider a particle that is bound by a force proportional to its displacement, F = -kx; the potential of the restoring force is V = (1/2)k x^2.

Part (a)  Define k = ω^2 m, En = (1/2) en ℏ ω, and α = Sqrt[ℏ/(ω m}].  Express Schrödinger's equation in terms of z, where x = α z, and show that the equation reduces to ψ''[z] == -(en ψ[z]) + z^2 ψ[z]

SetCoordinates[Cartesian[x,y,z]]

eq1 = 0 == schrodinger[1/2 k x^2, En] @ (ψ[x])

notation = {k -> ω^2 m, En -> (1/2) en ℏ ω}

αRule = {α->Sqrt[ℏ/(ω m)]}

eq2 = vChange[eq1,ψ,x,z,α z]

eq3a = Solve[eq2,ψ''[z]]//Flatten

eq3b = eq3a//.notation//Simplify

eq3c = eq3b//.αRule//Simplify

eq3 = eq3c//.{Rule->Equal}

Part (b)  Define a new function ψ[z] = Exp[-z^2 /2] h[z] and show that h[z] satisfies the equation h''[z] == h[z] - en h[z] + 2 z h'[z].  Use the user-defined operator diffSeriesOne to find a power series solution for h[z].  Show that if the values of en are integers, the power series terminates beyond a certain power of z.  verify that these solutions are Hermite polynomials.

ψRule = {ψ -> ((h[#] Exp[-#^2/2])&)}

eq4=(eq3//.ψRule)//ExpandAll

eq5=(Solve[eq4,h''[z]][[1,1]]//ExpandAll)/.{Rule->Equal}

diffSol=
	((diffSeriesOne[eq5,h,z,8,{h[0]->h0,h'[0]->hp0}]
		//Collect[#,{hp0,h0,z}]&
		)//Map[Simplify,#,{2}]&
		)

serOdd=(Coefficient[diffSol,hp0]//.{en->2 n+1}
/.n->{1,3,5,7}//Factor)

serEven=(Coefficient[diffSol,h0]//.{en->2 n+1}
/.n->{0,2,4,6}//Factor)

termEven[n_]=(-1)^(n/2) (n/2)! /(n)! HermiteH[n,z]

serEven/(termEven[#]& /@ {0,2,4,6}) //Factor

termOdd[n_]=(-1)^((n-1)/2) ((n-1)/2)! /(n)! /2 HermiteH[n,z]

serOdd/(termOdd[#]& /@ {1,3,5,7}) //Factor

Part (c)    Consider the equation h''[z] == h[z] - en h[z] + 2 z h'[z].  Let  en = 2n+1 and declare n to be an integer {0, 1, 2, 3, ...}.  Show that the solutions of these equations follow from the user-defined solutions in the Introduction (6.1).

n /: IntegerQ[n]=True;

eq6=eq5/.{en->(2 n+1)}//Expand

sol=DSolve[eq6,{h},z]//Flatten

Table[eq6/.sol,{n,0,8}]//ExpandAll

Part (d)  Normalize the wave function.  Plot the normalized wave function and the square of the normalized wave function for the first eight values of n.

ψ[z_,n_] = h[z] Exp[-z^2/2]//.sol

normConst[n_] := normConst[n] = 1/Sqrt[NIntegrate[ψ[z,n]^2,{z,-∞,∞}]]

normConst[#]& /@ {0,1,2,3,4,5,6,7,8}

Plot[
	Evaluate[Table[normConst[n] ψ[z,n] + 2 n,{n,0,7}]]
	,{z,-6,6}
	,Epilog->Plot[1.1 z^2,{z,-6,6}
				 ,PlotStyle->Thickness[0.01]
				 ,DisplayFunction->Identity
				 ][[1]]
	];

Plot[
	Evaluate[Table[(normConst[n] ψ[z,n])^2 + 2 n,{n,0,7}]]
	,{z,-6,6}
	,Epilog->Plot[1.1 z^2,{z,-6,6}
				 ,PlotStyle->Thickness[0.01]
				 ,DisplayFunction->Identity
				 ][[1]]
	];