6. Quantum Mechanics

Legal Notice, Disclaimer, and Book Ordering Information:

Null

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`ParametricPlot3D`"]

<< "D:\Mma\Inits\ch6init.m"

Clear["Global`*"];

6.2 Problems

6.2.3  Three Dimensional Schrödinger Equation

Problem 5:  The hydrogen atom in spherical coordinates

Consider Schrödinger's equation with the Coulomb potential V[r] = -Ze^2/r .  The angular dependence is given by Y[ℓ,m,θ,ϕ].  The radial function satisfies the equation
	0 ==  ((k r)^2 - ℓ(ℓ+1)) R[r] + 2r R'[r] + r^2 R''[r] where  k^2 = (En - V) 2 m/(ℏ^2) .  Because En is negative, set Wn = -En .

Part (a)   Find the normalized radial wave equation in therms of the orbital quantum number n and the angular momentum quantum number ℓ.  Normalizt the solution using (∫_0^∞)R[r]^2(r^2) dr = 1.

rEq = ((k r)^2 - ℓ(ℓ+1)) R[r] + 2r R'[r] + r^2 R''[r] == 0//ExpandAll

rule1 = {k -> Sqrt[2 m (En - V[r])]/ℏ
		,V[r] -> -Z e^2/r
		,En -> -Wn}

rEq2 = rEq//.rule1//ExpandAll

rSol = ( DSolve[rEq2,{R[r]},r]//Flatten//PowerExpand//Simplify)//.{Sqrt[x_^2]->x}//Simplify

rule2 = {Wn -> e^4 m Z^2/(2 n^2 ℏ^2)
		,e -> ℏ/Sqrt[m a0]}

rSol2 = (R[r]/.rSol)//.rule2//PowerExpand//Simplify

Series[HypergeometricU[-a,b,r],{r,∞,0}]

rSol3 = rSol2//.{C[1]->0, C[2]->1}

int/:IntegerQ[int]=True

n/:IntegerQ[n]=True

ℓ/:IntegerQ[ℓ]=True

H2LRule = {Hypergeometric1F1[a_,b_,c_]->(Gamma[b] Gamma[1-a] / Gamma[b-a]) LaguerreL[-a,b-1,c]} ;

rSol4 = rSol3/.H2LRule//Simplify

Integrate[ExpandAll[r^2*(rSol4//.{n->1,ℓ->0})^2],{r,0,∞}, GenerateConditions -> False]

norm[n_, ℓ_] := norm[n, ℓ] = Integrate[ExpandAll[r^2*(rSol4)^2],{r,0,∞}, GenerateConditions -> False]

Table[norm[n, ℓ],{n,1,3},{ℓ,0,n-1}]

rWave[n_,ℓ_,r_] := rWave[n,ℓ,r] = PowerExpand[rSol4/Sqrt[norm[n,ℓ]] ]

Table[Integrate[ExpandAll[rWave[n,ℓ,r]^2 * r^2],{r,0,∞}, GenerateConditions -> False],{n,1,3},{ℓ,0,n-1}]

(rWave[1, 0, r])

(rWave[2, #1, r]&)/@{0, 1}

(rWave[3, #1, r]&)/@{0, 1, 2}

Part (b)  Graph the radial probability density ρ[r] = R[r]^2(r^2) for the states n={1,2,3}.

value = {Z -> 1, a0 -> 1}; 
plot[n_, el_, rmax_] := 
   Plot[Evaluate[r^2*rWave[n, el, r]^2 /. value], {r, 0.01, rmax}, Ticks -> None, 
    DisplayFunction -> Identity];

Show[
      GraphicsArray[
        Evaluate[Table[plot[n, el, 10  n ], {n, 1, 3}, {el, 0, n - 1}]]]];

Part (c)  Plot the absolute value of the wave function for ℓ=0, 1, 1nd 2 for all the allowable values of m and for fixed r.

plot[el_, m_] := 
      SphericalPlot3D[
        Evaluate[Abs[SphericalHarmonicY[el, m, θ, ϕ]]], {
          θ, 0, π}, {ϕ, 0, 2 π}, Boxed -> False, 
        Axes -> False, DisplayFunction -> Identity];

pt1 = 
      Table[plot[ℓ, m], {ℓ, 0, 2}, {m, -ℓ, 
          ℓ}];

Show[GraphicsArray[pt1]];