7. Relativity and Cosmology

Legal Notice, Disclaimer, and Book Ordering Information:

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`PlotField3D`"]

<< "D:\Mma\Inits\ch7init.m"

Clear["Global`*"];

7.2 Problems

7.2.1  Special Relativity Problems

Problem 5:  One-dimensional motion of a relativistic particle with constant acceleration

Consider a relativistic particle acclerated by a constant force directed along the x axis.  Assume the particle is moving along the x axis and solve for its distance as a function of coordinate time t.  The motion is assumed to be describrd by the relativistic equaiton:
		d/dt (v[t]/Sqrt[1 - (v[t])^2]) = g
where v[t] = x'[t], t is the coordinate time, c = 1, and g is the acceleration constant due to the force.

Part (a) Solve for v[t] and x[t] and assume x[0]=0 and v[0]=v0.  Show that the solution has the expected non-relativistic limit.

eqMotion = D[v[t]/Sqrt[1-v[t]^2],t] == g

eq1 = (DSolve[{eqMotion},v[t],t][[2]]
		/.{Rule->Equal}
		//Simplify
		//PowerExpand)

eq2 = eq1/.{v[t]->x'[t]}

dsol2 = DSolve[eq2,x[t],t,{DSolveConstants->CC}]//Flatten//PowerExpand//Simplify

initialConditions =
	{(x[t]//.dsol2//.{t->0})==x0,(D[(x[t]//.dsol2),t]//.{t->0})==v0}//Simplify

cRule = Solve[initialConditions,{CC[1],C[1]}][[2]]//Simplify

relResult = ( x[t]/.dsol2/.cRule)//Simplify

sRule = {Sqrt[a_] Sqrt[b_] :> Sqrt[a b]
		,1/(Sqrt[a_] Sqrt[b_]) :> 1/Sqrt[a b]
		,I Sqrt[a_] :> Sqrt[-a]};

γRule = {(1 - v0^2) -> 1/γ^2
		,(-1 + v0^2) -> -1/γ^2
		,I Sqrt[-1 + v0^2] -> 1/γ};

relResult2 = (relResult//.γRule//PowerExpand)//.sRule//ExpandAll//PowerExpand

nonRelResult = ((Series[relResult,{t,0,2},{v0,0,2}]//Normal//Simplify)//.{v0^2->0})

(({relResult,D[relResult,t]}/.{t->0})/.γRule//PowerExpand)

({nonRelResult,D[nonRelResult,t]}/.{t->0})

Part (b)  Plot x[t] for the relativistic and non-relativistic solutions.

values = {x0->0,v0->1/2,g->-0.1}

Plot[{relResult,nonRelResult}/.values//Evaluate
	,{t,0,12}
	,GridLines->Automatic
	,AxesLabel->{"t","x[t]"}
	,PlotStyle->{{Thickness[0.01]}
				,{Dashing[{0.06,0.1}],Thickness[0.001]}}
	,Epilog->Graphics[
		{Text[FontForm["Relativistic",{"Courier-Bold",10}],{10,1.3}]
		,Text[FontForm[nonRelResult,{"Courier-Bold",10}],{8,0.3}]
	}][[1]]
];