7. Relativity and Cosmology

Legal Notice, Disclaimer, and Book Ordering Information:

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`PlotField3D`"]

<< "D:\Mma\Inits\ch7init.m"

Clear["Global`*"];

7.2 Problems

7.2.1  Special Relativity Problems

Problem 6:  Two-dimensional motion of a relativistic particle in a uniform electric field.

A particle with mass m and charge e moves in a static uniform electric field E0.  The electric field is assumed to be along the y axis.  The equations of motion for the particle are: px'[t]=0, py'[t]=eE0, and pz'[t]=0, where {px,py,pz} is the three-space components of thw four-momentum vector.

Part (a) Solve for the velocity and momentum of the particle as explicit functions of time.  Assume that the initial momentum is perpendicular to the electric field, {px[0]=px0, py[0]=0,  pz[0]=0}.  Find the non-relativistic limit.

eqMotion = {px'[t]==0, py'[t]== e E0, pz'[t] == 0}

initial = {px[0]==p0x, py[0]== 0, pz[0] == 0}

momRule = DSolve[eqMotion~Join~initial,{px[t],py[t],pz[t]},t]//Flatten

pVec[t_] = {px[t],py[t],pz[t]}

eq1 = m γ == Sqrt[pVec[t].pVec[t] + m^2 /.momRule]

γRule = Solve[eq1,γ]//Flatten

eq2 = (m γ x'[t] == px[t])/.momRule/.γRule

xRule = DSolve[{eq2,x[0]==0},x[t],t]//Flatten//PowerExpand//ExpandAll

yEq = (m γ y'[t] == py[t]) /.momRule/.γRule

yRule = DSolve[{yEq,y[0]==0},y[t],t]//Flatten

relXY = {x[t],y[t]} /.xRule/.yRule

nonRelXY = (Map[Series[#,{t,0,2}]&,relXY]/.{p0x^2->0})//PowerExpand//Normal

Part (b)  Compare the plots for the nonrelativistic linit with the relativistic plots.

values = {m->1, e->1, E0->0.1, p0x->0.1}

Clear[plotOp]

plotOp[eqs_List,axis_,tRange_] :=
Plot[eqs/.values//Evaluate
	,{t,0,tRange}
	,GridLines->Automatic
	,AxesLabel->{"t",axis}
	,PlotStyle->{{Thickness[0.01]}
				,{Dashing[{0.06,0.1}],Thickness[0.001]}}
	,DisplayFunction->Identity ];

Show[GraphicsArray[
	{plotOp[{relXY[[1]],nonRelXY[[1]]},"x",30]
	,plotOp[{relXY[[2]],nonRelXY[[2]]},"y",30]} ]];