7. Relativity and Cosmology

Legal Notice, Disclaimer, and Book Ordering Information:

Null

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`PlotField3D`"]

<< "D:\Mma\Inits\ch7init.m"

Clear["Global`*"];

7.2 Problems

7.2.2  General Relativity and Cosmology Problems

Problem 5:  Time It Takes to Fall into a Black Hole

Consider the Schwartzschild geodesics.  Assume that the geodesic four-velocity is given by v = {t'[s],r'[s],0,0}, where E = t'[s](1 - 2m/r).  Let the initial conditions be r'[0]=0 and r[0]=r0.

Part (a)  Derive an equation for r'[s] from the timelike condition 1 = v . η . v  .

construle = {t'[s] -> en/(1 - (2*m)/r[s]), 
			 t''[s] -> D[en/(1 - (2*m)/r[s]), s]};

m/:Sign[m]=1;
en/:Sign[en]=1;

vel = {t'[s],r'[s], 0, 0}; 
met = ssMet /. ssComp /. r -> r[s];

eq1 = 1 == met . vel . vel /. construle//Simplify

eq2 = Solve[eq1,r'[s]][[1,1]] /.{Rule -> Equal}//PowerExpand//Simplify

eq3 = 0 == eq2[[2]] /. s -> 0 /. r[0] -> r0

rprimerule = PowerExpand[MapAt[Factor, 
    Solve[{eq2, eq3}, {r'[s], en}][[2]], {1, 2, 2, 1}]]

radialEq = rprimerule[[1]] /. Rule -> Equal//ExpandAll//PowerExpand

Part (b)  Verify from the user-defined function geodesic that {t'[s],r'[s],0,0} satisfies the geodesic equations, where t'[s] is given by the first integral and r'[s] is given by the timelike condition derived in Part (a).

geovel = vel /. (radialEq /. Equal -> Rule) /. construle

metric = ssMet /. ssComp

geoEq = geodesic[metric, {t, r, θ, ϕ}];

Short[geoEq,4]

eq4 = Simplify[geoEq /. {ϕ -> (ϕ0 & ), θ -> (θ0 & )}]

Simplify[eq4 /. 
     Derivative[2][r][s] -> D[Derivative[1][r][s]
     /. rprimerule, s] /.construle /. rprimerule]

Part (c)  Derive an expression for the proper time as a function of the radial  position.

rchange = r -> (r0*Cos[x[#1]]^2 & )

r0/:Sign[r0]=1

radialEq2 = radialEq /.rchange//PowerExpand//Simplify

eq5 = PowerExpand[Simplify[Solve[radialEq2,x'[s]][[1,1]]]]//Simplify

Stimex = Simplify[Integrate[1/x'[s] /. eq5, {x[s], 0, x}]]

xrule = Solve[r == (r[s] /. rchange), x[s]][[4]] /. x[s] -> x

Stime = Stimex /. xrule

Part (d)  Derive an expression for the coordinate time as a function of the radial  position.

eq6 = Simplify[PowerExpand[ExpandAll[-(t'[s]/
           r'[s]) /. construle /. rprimerule /. r[s] -> r[t]]]]

eq7 = Integrate[eq6, r[t]]//ExpandAll//PowerExpand//Simplify

r0lim = (Limit[eq7,r[t] -> r0]) //ExpandAll//PowerExpand//Simplify

Ttime = (r0lim - (eq7 /. r[t] -> r))//Simplify//PowerExpand

Part (e)  Plot the proper and coordinate times as a function of r.

value = {m -> 1, r0 -> 8};

pt1 = Plot[Evaluate[(Chop[#1, 1/10^5] & )[Ttime /. value]], 
    {r, 2.008999999999999, 7.99}
    ,DisplayFunction -> Identity];

pt2 = Plot[Evaluate[Stime /. value], {r, 0, 8}
			, DisplayFunction -> Identity];

Show[{pt1, pt2, Graphics[{Line[{{2, 0}, {2, 40}}], 
      Text[FontForm["Proper Time", {"Times-Roman", 10}], 
       {1.199999999999999, 22}], 
      Text[FontForm["Coordinate Time", {"Times-Roman", 10}], {4.5, 30}], 
      Text[FontForm["r=2 m ", {"Times-Roman", 10}], {2.6, 10}]}]}, 
   AxesLabel -> {"Distance", "Time"}, DisplayFunction -> $DisplayFunction, 
   PlotRange -> {0, 40}];