7. Relativity and Cosmology

Legal Notice, Disclaimer, and Book Ordering Information:

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`PlotField3D`"]

<< "D:\Mma\Inits\ch7init.m"

Clear["Global`*"];

7.2 Problems

7.2.2  General Relativity and Cosmology Problems

Problem 7:  Field Equations for Robertson-Walker cosmology

Consider the Robertson-Walker metric defined by the diagonal matrix (Subscript[η, RW]) = DiagonalMatrix[{1, -R[t]^2/(1-(Subscript[κ, RW]) (r^2)), -R[t]^2 (r^2), -R[t]^2 (r^2) Sin[θ]^2}].  Assume the model is defined by the covariant energy-momentum tensor (T^ij) = (ρ + P)(V^i) (V^j) - (g^ij)(P) where (V^i) = {1,0,0,0}.

Part (a)  From Einstein's equation with a cosmological constant λ, show that R[t] obeys the following two equations:
                    R''[t]==(1/3) R[t] 
          (λ - 12 G π P[t] - 4 G π ρ[t])
            
                    ((R'[t])^2)==(1/3) (
            -3 κRW + 
              R[t]^2 (λ + 8 G π ρ[t]))

RWmet = 
  DiagonalMatrix[{1, -(R[t]^2/(1 - κRW r^2)), 
    -(R[t]^2 r^2), -(R[t]^2 r^2 Sin[θ]^2)}]

RWchrist = christ[RWmet]

RWcurve = curvR[RWchrist]//Simplify;  Short[RWcurve,12]

einsteinT = einstein[RWcurve,RWmet]

vel = {1,0,0,0}	(* Contravariant four-velocity *)

covel = RWmet.vel	(* Contravariant four-velocity *)

T = Table[
	(ρ[t] + press[t])covel[[i]]covel[[j]]-
			RWmet[[i,j]]press[t],
			{i,4},{j,4}]

eq1 = Map[Flatten,einsteinT == - 8 π G T - λ RWmet]//
	Thread//Select[#1,FreeQ[#,True]&]&//Simplify

fieldEq = (Solve[eq1/.R'[t]->Sqrt[x],{R''[t],x}][[1]]/.
	x->R'[t]^2//Simplify)/.Rule->Equal

Part (b)  Assume that the pressure P[t] and density ρ[t] are related by the equation of state P[t] = α ρ[t].  Show from conservation of energy-momentum (Subscript[T, ij]^ij) = 0 that:
                           ρ[t] =  ρ[0] (((R0/R[t]))^(3 (1 + α)))

conT = Table[(ρ[t] + press[t])vel[[i]]vel[[j]]-
			Inverse[RWmet][[i,j]]press[t],
			{i,4},{j,4}]//Simplify

dconT[conT_,christ_,var_:{t,r,θ,ϕ}] :=
	Simplify[Expand[Table[
		D[conT[[i,j]],var[[k]] ]+
			Sum[christ[[i,s,k]]conT[[s,j]]+
				christ[[j,s,k]]conT[[i,s]],
					{s,4}],{i,4},{j,4},{k,4}] ]]

eq2 = dconT[conT,RWchrist]

eq3 = Table[Sum[eq2[[i,s,s]],{s,1,4}],{i,1,4}]

eq4 = eq3[[1]]==0

eqState = {press[t] -> α ρ[t]}

eq5 = (DSolve[{eq4/.eqState,R[0]==R0},R[t],t][[1,1]]//Simplify)/.
	Rule->Equal//PowerExpand

ρRule = Solve[eq5/.ρ[t]->x,x][[1,1]]/.x->ρ[t]//PowerExpand//Simplify

Part (c)  Let α = 0 and show that the rquations for R'[t]^2 and R''[t] can be written:
		R''[t]==(1/3) R[t] λ - 
          (4/3)  G π ((Subscript[R, 0])^3) ρ[t]/R[t]^2
		((R'[t])^2)== -κRW + (1/3) λ R[t]^2 + 
          (8/3) G π ((Subscript[R, 0])^3) ρ[0]/R[t]

eq7 = fieldEq/.ρRule/.eqState/.α->0//ExpandAll//Simplify