7. Relativity and Cosmology

Legal Notice, Disclaimer, and Book Ordering Information:

Setup

\(Clear["Global`*"]; 
Off[General::spell]; 
Off[General::spell1]; 
    \)

Needs["Calculus`VectorAnalysis`"]

Needs["Graphics`PlotField3D`"]

<< "D:\Mma\Inits\ch7init.m"

Clear["Global`*"];

7.2 Problems

7.2.2  General Relativity and Cosmology Problems

Problem 9:  The expansion and age of the universe in the Standard Model

The standard cosmological models are Robertson-Walker models with zero pressure and a zero cosmological parameter.  The scale factor obeys the equation R'[t]^2 = - κRW + 2 qo Ho^2 R[0]^3/R[t] , where R[0] = (1/Ho) Sqrt[κRW/(2 qo - 1)] for κRW ≠  0.

Part (a)  Find the solutions for R[t] and age for the model when κRW = 0  (flat).  Graph the results.

eq1 = R'[t]^2 == Ho^2 R[0]^3/R[t]

eq2 = t == Integrate[Sqrt[1/eq1[[2]]],R[t]]//PowerExpand

age0 = eq2[[2]]/.R[t]->R[0]

scale0 = Solve[eq2,R[t]][[2,1]]/.Rule->Equal

Plot[Evaluate[scale0[[2]]/.{Ho->1,R[0]->1}],{t,0,1}
		,Frame->True
		,PlotLabel-> scale0
		,FrameLabel->{"Time (Hubble units)","R[t}"," "," "}
		,FrameTicks->{{{0,"Big Bang"},{1/3,"1/(3Ho)"}
					  ,{2/3,"Now"},{1,"1/Ho"}}
					  ,{0,{1/2," R[0]/2 "},{1,"R[0]"}}}
		,Epilog->Graphics[{PointSize[.03],Point[{2/3,1}]}][[1]]];

Part (b)  Find the solutions for R[t] and age for the model when κRW = 1  (closed).  Graph the results.

eq3 = R'[t]^2 == -1 + 2 qo Ho^2 R[0]^3/R[t]

R0rule = {R[0]-> 1/Ho  Sqrt[1/(2 qo - 1)]}

eq4 = eq3/.R0rule//PowerExpand

change = R->((2 qo/(Ho(2 qo - 1)^(3/2))Sin[x[#]]^2)&)

scale1 = R[x]/.change/.x[x]->x//PowerExpand

eq4a = eq4/.change//Simplify

eq5 = Solve[eq4a,x'[t]][[2]]/.
(z_)^(3/2)->-I(-z)^(3/2)

time1 = Integrate[(1/x'[t]/.eq5),{x[t],0,x}]

solx = Solve[R[0]==scale1,x]/.R0rule//ExpandAll//PowerExpand

xage = solx[[2]]

age1 = time1/.xage//ExpandAll//Simplify

value = {Ho->1,qo->1}

label = Graphics[{PointSize[.03]
		,Text[FontForm[(time1/.xage/.value//N[#,2]&)"/Ho==age"
			,{"Times-Roman",10}],{2,1}]
		,Point[{time1/.x->π/2/.value
				,scale1/.x->π/2/.value}]								,Point[{time1/.xage/.value
				,scale1/.xage/.value}]	}];

ParametricPlot[Evaluate[{time1,scale1}/.value],{x,0,π}
		,Frame->True
		,PlotLabel-> "Closed Model, qo=1"
		,FrameLabel->{"t","R[t}"," "," "}
		,FrameTicks->{{{0,"Bang"},{age1/.value//N,"Now"}
					  ,{3*age1/.value//N,"3*age"}
					  ,{time1/.value/.x->π/2,"max"}
					  ,{9*age1/.value//N,"9*age"}
					  ,{time1/.value/.x->π,"Crunch"}}
				,{0,1/2,{1,"R[0]"},1.5,2}}
		,Epilog->label[[1]]	];

Part (c)  Find the solutions for R[t] and age for the model when κRW = -1  (open).  Graph the results.

eq6 = R'[t]^2 == 1 + 2 qo Ho^2 R[0]^3/R[t]

R0rule = {R[0]-> 1/Ho  Sqrt[1/(1 - 2 qo)]}

eq7 = eq6/.R0rule//PowerExpand

change = R->((2 qo/(Ho(1 -2 qo)^(3/2))Sinh[x[#]]^2)&)

scale2 = R[x]/.change/.x[x]->x//PowerExpand

eq7a = eq7/.change//Simplify

eq8 = Solve[eq7a,x'[t]][[2]]

time2 = Integrate[(1/x'[t]/.eq8),{x[t],0,x}]

solx2 = Solve[R[0]==scale2,x]/.R0rule//PowerExpand

xage = solx2[[2]]

age2 = time2/.xage

value = {Ho->1,qo->.02}

label = Graphics[{PointSize[.03]
		,Text[FontForm[(time2/.xage/.value//N[#,2]&)"/Ho==age"
			,{"Times-Roman",10}]
			,{1.5 time2/.xage/.value,scale2/.xage/.value}]
		,Point[{time2/.xage/.value
				,scale2/.xage/.value}]	}];

ParametricPlot[Evaluate[{time2,scale2}/.value],{x,0,3}
		,Frame->True
		,PlotLabel-> "Open Model, qo=.02"
		,FrameLabel->{"t","R[t}"," "," "}
		,FrameTicks->{{{0,"Bang"}
					  ,{age2/2/.value//N,"1/2*age"}
					  ,{age2/.value//N,"age"}
					  ,{1.5*age2/.value//N,"3/2*age"}
					  ,{2*age2/.value//N,"2*age"}
					  }
				,{0,1/2,{1,"R[0]"},1.5,2}}
		,Epilog->label[[1]]	];